Verilog入門｜Icarus Verilogで回路を書いて動かす

# Ubuntu / Debian
sudo apt-get install iverilog
 
# macOS（Homebrew）
brew install icarus-verilog

iverilog -V

Icarus Verilog version 12.0 (stable) ()

module and_gate(input a, input b, output out);
  assign out = a & b;   // aとbのAND。常にこの配線が成立している
endmodule
 
module tb;
  reg a, b;      // テストベンチ側から値を入れる「レジスタ」
  wire out;      // 回路からの出力を受ける「配線」
  and_gate uut(a, b, out);   // 回路を1つ、配置する
 
  initial begin
    $display("a b | out");
    a=0; b=0; #1 $display("%b %b | %b", a, b, out);
    a=0; b=1; #1 $display("%b %b | %b", a, b, out);
    a=1; b=0; #1 $display("%b %b | %b", a, b, out);
    a=1; b=1; #1 $display("%b %b | %b", a, b, out);
  end
endmodule

iverilog -g2012 -o and_gate.out and_gate.v
vvp and_gate.out

a b | out
0 0 | 0
0 1 | 0
1 0 | 0
1 1 | 1

module full_adder(input a, input b, input cin, output s, output cout);
  assign s = a ^ b ^ cin;                    // 和
  assign cout = (a & b) | (b & cin) | (a & cin);  // 桁上がり
endmodule
 
module adder4(input [3:0] a, input [3:0] b, output [3:0] s, output cout);
  wire c1, c2, c3;   // 桁上がりを次の桁へ渡す配線
  full_adder fa0(a[0], b[0], 1'b0, s[0], c1);
  full_adder fa1(a[1], b[1], c1,   s[1], c2);
  full_adder fa2(a[2], b[2], c2,   s[2], c3);
  full_adder fa3(a[3], b[3], c3,   s[3], cout);
endmodule

module tb_adder4;
  reg [3:0] a, b;
  wire [3:0] s;
  wire cout;
  integer i, j, errors;
  adder4 uut(a, b, s, cout);
 
  initial begin
    errors = 0;
    for (i = 0; i < 16; i = i + 1) begin
      for (j = 0; j < 16; j = j + 1) begin
        a = i; b = j;
        #1;
        if ((s + (cout << 4)) !== (i + j)) errors = errors + 1;
      end
    end
    a = 4'd6; b = 4'd5; #1;
    $display("%0d + %0d = %0d (cout=%b)", a, b, s, cout);
    if (errors == 0) $display("4bit adder 256 patterns: OK");
    else $display("4bit adder: %0d errors", errors);
  end
endmodule

iverilog -g2012 -o adder4.out adder4.v tb_adder4.v
vvp adder4.out

6 + 5 = 11 (cout=0)
4bit adder 256 patterns: OK